; h8/300hのブートモード用スタートアップルーチン
; Copyleft,1999,Yukio Mituiwa

	.h8300h
	.section .text
	.global	___start
___start:
	;; スタックポインタの設定
	mov.l	#_stack,sp
	;; ROMのDATAをRAMに転送
	mov.l	#___dtors_end,er0
	mov.l	#___data,er1
	mov.l	#_edata,er2
.mvdata:
	mov.w	@er0,r3
	mov.w	r3,@er1
	adds	#2,er0
	adds	#2,er1
	cmp.l	er2,er1
	blo	.mvdata
	;; mainルーチン
	jsr	@_main
	bra	___start




	.global _waitloop
;				; states
;	jsr	_waitloop	; 8
waitloop1:
	nop			; 2
	nop			; 2
	nop			; 2
	nop			; 2
	nop			; 2
_waitloop:
	dec	#1,er0		; 2
	bne	waitloop1	; 4
	rts			; 8



	.section .stack
_stack:	.long 	1
